趣味問題：你能用Reflection.Emit生成這段代碼嗎？（答案）
在上一篇博客中我提出了一個問題：如何用.NET的Reflection.Emit生成等價于下面VB代碼的三個類型：
Implements B.I
End Class
Class B
Inherits A
Interface I
End Interface
End Class
這個問題的難點在于三個類型有循環依賴關系：A實現了接口B.I，因此A依賴于I；B是A的子類，因此B依賴于A；接口I是B的嵌套類型，因此I依賴于B。使用Reflection.Emit的時候最大的問題就是不管以何種順序調用CreateType方法總會出現依賴項有問題的錯誤。下面是一個簡單的嘗試但是無法成功：
Sub Main()
Dim name = New AssemblyName("test")
Dim dasm = AppDomain.CurrentDomain.DefineDynamicAssembly(name, AssemblyBuilderAccess.RunAndSave)
Dim dmod = dasm.DefineDynamicModule(name.Name, name.Name + ".dll")
Dim tA = dmod.DefineType("A", TypeAttributes.Public Or TypeAttributes.Class)
Dim tB = dmod.DefineType("B", TypeAttributes.Public Or TypeAttributes.Class, tA)
Dim tI = tB.DefineNestedType("I", TypeAttributes.NestedPublic Or TypeAttributes.Interface Or TypeAttributes.Abstract)
tA.AddInterfaceImplementation(tI)
tA.CreateType()
tB.CreateType()
tI.CreateType()
dasm.Save(name.Name + ".dll")
End Sub
End Module
我們發現，這里存在的問題主要是：
- Reflection.Emit無法在這種情況下生成B類型的構造函數
- 創建類型的時候會發生類型解析錯誤
因此我們分別解決這兩個問題。首先既然無法自動生成B的構造函數那么我們手工來創造它。這可以用TypeBuilder的DefineConstructor來做到。至于A類型的基類是Object所以直接用DefineDefaultConstructor即可。注意構造函數有很多必須的屬性，包括PrivateScope、HideBySig、SpecialName、RTSpecialName等，必須都加上（否則使用它的時候會出很多錯）。接下來就是循環引用導致找不到的問題，我們可以處理AppDomain的TypeResolve事件手動處理循環引用的問題。下面就是完整的方案：
Imports System.Reflection.Emit
Module Program
Sub Main()
Dim name = New AssemblyName("test")
Dim dasm = AppDomain.CurrentDomain.DefineDynamicAssembly(name, AssemblyBuilderAccess.RunAndSave)
Dim dmod = dasm.DefineDynamicModule(name.Name, name.Name + ".dll")
Dim tA = dmod.DefineType("A", TypeAttributes.Public Or TypeAttributes.Class)
Dim tB = dmod.DefineType("B", TypeAttributes.Public Or TypeAttributes.Class, tA)
Dim tI = tB.DefineNestedType("I", TypeAttributes.NestedPublic Or TypeAttributes.Interface Or TypeAttributes.Abstract)
tA.AddInterfaceImplementation(tI)
Const ctorAttr As MethodAttributes = MethodAttributes.Public Or MethodAttributes.PrivateScope Or
MethodAttributes.HideBySig Or MethodAttributes.SpecialName Or MethodAttributes.RTSpecialName
Dim ctorA = tA.DefineDefaultConstructor(ctorAttr)
Dim ctorB = tB.DefineConstructor(ctorAttr,
CallingConventions.Standard, {})
With ctorB.GetILGenerator
.Emit(OpCodes.Ldarg_0)
.Emit(OpCodes.Call, ctorA)
.Emit(OpCodes.Ret)
End With
AddHandler AppDomain.CurrentDomain.TypeResolve,
Function(sender As Object, e As ResolveEventArgs)
Select Case e.Name
Case "A" : Return tA.CreateType.Assembly
Case "B" : Return tB.CreateType.Assembly
Case "I" : Return tI.CreateType.Assembly
End Select
Return Nothing
End Function
tA.CreateType()
tB.CreateType()
tI.CreateType()
dasm.Save(name.Name + ".dll")
End Sub
End Module
這樣生成的程序集無論是通過Reflector反編譯還是使用C#/VB來引用都是正確的，和真正的VB編譯器編譯出來是一樣的。
這個問題的緣由是VB Team的PM Lucian Wischick的博客上提出了這個問題。微軟的VB Team正在將C++編寫的VB編譯器移植成VB代碼。他們正在研究托管編譯器的后端可不可以使用Reflection.Emit來實現。由于VB支持這種循環類型依賴的代碼，所以他們很頭疼遇到的問題。幸好一篇回復解決了這個問題。希望采用Reflection.Emit作為編譯器后端的同學可以參考一下這種方法。
留言列表
